stockholm/tv/5pkgs/simple/q/default.nix

{ pkgs, ... }:
with import <stockholm/lib>;
let
  q-cal = let

    # Maximum width of cal's output.
    calwidth = 23;

    # Number of space characters between two calendars.
    hspace = 2;

    # Return number of columns required to print n calenders side by side.
    need_width = n:
      assert n >= 1;
      n * calwidth + (n - 1) * hspace;

    pad = /* sh */ ''{
      ${pkgs.gnused}/bin/sed '
            # rtrim
            s/ *$//

            # delete last empty line
            ''${/^$/d}
          ' \
        | ${pkgs.gawk}/bin/awk '{printf "%-${toString calwidth}s\n", $0}' \
        | ${pkgs.gnused}/bin/sed '
              # colorize header
              1,2s/.*/&/

              # colorize week number
              s/^[ 1-9][0-9]/&/
            '
    }'';
  in /* sh */ ''
    cols=$(${pkgs.ncurses}/bin/tput cols)
    ${pkgs.coreutils}/bin/paste \
        <(if test $cols -ge ${toString (need_width 3)}; then
          ${pkgs.utillinux}/bin/cal -mw \
              $(${pkgs.coreutils}/bin/date +'%m %Y' -d 'last month') \
            | ${pad}
        fi) \
        <(if test $cols -ge ${toString (need_width 1)}; then
          ${pkgs.utillinux}/bin/cal -mw \
            | ${pkgs.gnused}/bin/sed '
                # colorize day of month
                s/\(^\| \)'"$(${pkgs.coreutils}/bin/date +%e)"'\>/&/
              ' \
            | ${pad}
        fi) \
        <(if test $cols -ge ${toString (need_width 2)}; then
          ${pkgs.utillinux}/bin/cal -mw \
              $(${pkgs.coreutils}/bin/date +'%m %Y' -d 'next month') \
            | ${pad}
        fi) \
      | ${pkgs.gnused}/bin/sed '
          s/^\t//
          s/\t$//
          s/\t/${lpad hspace " " ""}/g
        '
  '';

  q-isodate = /* sh */ ''
    ${pkgs.coreutils}/bin/date \
        '+%Y-%m-%dT%H:%M:%S%:z'
  '';

  # Singapore's red is #ED2E38
  q-sgtdate = /* sh */ ''
    TZ=Asia/Singapore \
    ${pkgs.coreutils}/bin/date \
        '+%Y-%m-%dT%H:%M:%S%:z'
  '';

  q-utcdate = /* sh */ ''
    ${pkgs.coreutils}/bin/date -u \
        '+%Y-%m-%dT%H:%M:%S%:z'
  '';

  q-gitdir = /* sh */ ''
    if test -d .git; then
      #git status --porcelain
      branch=$(
        ${pkgs.git}/bin/git branch \
          | ${pkgs.gnused}/bin/sed -rn 's/^\* (.*)/\1/p'
      )
      echo "± $LOGNAME@''${HOSTNAME-$(${pkgs.nettools}/bin/hostname)}:$PWD .git $branch"
    fi
  '';

  q-intel_backlight = /* sh */ ''
    cd /sys/class/backlight/intel_backlight
    </dev/null exec ${pkgs.gawk}/bin/awk '
      END {
        getline actual_brightness < "actual_brightness"
        getline max_brightness < "max_brightness"
        getline brightness < "brightness"
        printf "intel_backlight %d%% %d/%d\n" \
            , actual_brightness / max_brightness * 100 \
            , actual_brightness \
            , max_brightness
      }
    '
  '';

  q-power_supply = let
    power_supply = pkgs.writeBash "power_supply" ''
      set -efu
      uevent=$1
      eval "$(${pkgs.gnused}/bin/sed -n '
        s/^\([A-Z_]\+=[0-9A-Za-z_-]*\)$/export \1/p
      ' $uevent)"
      case $POWER_SUPPLY_NAME in
        AC)
          exit # not battery
          ;;
      esac
      exec </dev/null
      exec ${pkgs.gawk}/bin/awk '
        function die(s) {
          printf "%s: %s\n", name, s
          exit 1
        }

        function print_hm(h, m) {
          m = (h - int(h)) * 60
          return sprintf("%dh%dm", h, m)
        }

        function print_bar(n, r, t1, t2, t_col) {
          t1 = int(r * n)
          t2 = n - t1
          if (r >= .42)     t_col = "1;32"
          else if (r >= 23) t_col = "1;33"
          else if (r >= 11) t_col = "1;31"
          else              t_col = "5;1;31"
          return sgr(t_col) strdup("■", t1) sgr(";30") strdup("■", t2) sgr()
        }

        function sgr(p) {
          return "\x1b[" p "m"
        }

        function strdup(s,n,t) {
          t = sprintf("%"n"s","")
          gsub(/ /,s,t)
          return t
        }

        END {
          name = ENVIRON["POWER_SUPPLY_NAME"]

          charge_unit = "Ah"
          charge_now = ENVIRON["POWER_SUPPLY_CHARGE_NOW"] / 10^6
          charge_full = ENVIRON["POWER_SUPPLY_CHARGE_FULL"] / 10^6

          current_unit = "A"
          current_now = ENVIRON["POWER_SUPPLY_CURRENT_NOW"] / 10^6

          energy_unit = "Wh"
          energy_now = ENVIRON["POWER_SUPPLY_ENERGY_NOW"] / 10^6
          energy_full = ENVIRON["POWER_SUPPLY_ENERGY_FULL"] / 10^6

          power_unit = "W"
          power_now = ENVIRON["POWER_SUPPLY_POWER_NOW"] / 10^6

          voltage_unit = "V"
          voltage_now = ENVIRON["POWER_SUPPLY_VOLTAGE_NOW"] / 10^6
          voltage_min_design = ENVIRON["POWER_SUPPLY_VOLTAGE_MIN_DESIGN"] / 10^6

          #printf "charge_now: %s\n", charge_now
          #printf "charge_full: %s\n", charge_full
          #printf "current_now: %s\n", current_now
          #printf "energy_now: %s\n", energy_now
          #printf "energy_full: %s\n", energy_full
          #printf "energy_full: %s\n", ENVIRON["POWER_SUPPLY_ENERGY_FULL"]
          #printf "energy_full: %s\n", ENVIRON["POWER_SUPPLY_ENERGY_FULL"] / 10^6
          #printf "power_now: %s\n", power_now
          #printf "voltage_now: %s\n", voltage_now

          if (current_now == 0 && voltage_now != 0) {
            current_now = power_now / voltage_now
          }
          if (power_now == 0) {
            power_now = current_now * voltage_now
          }
          if (charge_now == 0 && voltage_min_design != 0) {
            charge_now = energy_now / voltage_min_design
          }
          if (energy_now == 0) {
            energy_now = charge_now * voltage_min_design
          }
          if (charge_full == 0 && voltage_min_design != 0) {
            charge_full = energy_full / voltage_min_design
          }
          if (energy_full == 0) {
            energy_full = charge_full * voltage_min_design
          }

          if (charge_now == 0 || charge_full == 0) {
            die("unknown charge")
          }

          charge_ratio = charge_now / charge_full

          out = out name
          out = out sprintf(" %s", print_bar(10, charge_ratio))
          out = out sprintf(" %d%", charge_ratio * 100)
          out = out sprintf(" %.2f%s", charge_now, charge_unit)
          if (current_now != 0) {
            out = out sprintf("/%.1f%s", current_now, current_unit)
          }
          out = out sprintf(" %d%s", energy_full, energy_unit)
          if (power_now != 0) {
            out = out sprintf("/%.1f%s", power_now, power_unit)
          }
          if (current_now != 0) {
            out = out sprintf(" %s", print_hm(charge_now / current_now))
          }

          print out
        }
      '
    '';
  in ''
    for uevent in /sys/class/power_supply/*/uevent; do
      ${power_supply} "$uevent" || :
    done
  '';

  q-virtualization = /* sh */ ''
    echo "VT: $(${pkgs.systemd}/bin/systemd-detect-virt)"
  '';

  q-wireless = /* sh */ ''
    for dev in $(
      ${pkgs.iw}/bin/iw dev \
        | ${pkgs.gnused}/bin/sed -n 's/^\s*Interface\s\+\([0-9a-z]\+\)$/\1/p'
    ); do
      inet=$(${pkgs.iproute}/bin/ip addr show $dev \
        | ${pkgs.gnused}/bin/sed -n '
            s/.*inet \([0-9]\+\.[0-9]\+\.[0-9]\+\.[0-9]\+\).*/\1/p
          ') \
        || unset inet
      ssid=$(${pkgs.iw}/bin/iw dev $dev link \
        | ${pkgs.gnused}/bin/sed -n '
            s/.*\tSSID: \(.*\)/\1/p
          ') \
        || unset ssid
      echo "$dev''${inet+ $inet}''${ssid+ $ssid}"
    done
  '';

  q-online = /* sh */ ''
    if ${pkgs.curl}/bin/curl -s google.com >/dev/null; then
      echo 'online'
    else
      echo offline
    fi
  '';

  q-thermal_zone = /* sh */ ''
    for i in /sys/class/thermal/thermal_zone*; do
      type=$(${pkgs.coreutils}/bin/cat $i/type)
      temp=$(${pkgs.coreutils}/bin/cat $i/temp)
      printf '%s %s°C\n' $type $(echo $temp / 1000 | ${pkgs.bc}/bin/bc)
    done
  '';

  q-todo = /* sh */ ''
    TODO_file=$PWD/TODO
    if test -e "$TODO_file"; then
      ${pkgs.jq}/bin/jq -Rrs <"$TODO_file" -f ${pkgs.writeJq "q-todo.jq" ''
        split("\n") | map(
          (match("^([0-9]+-\\d{2}-\\d{2})\\s+(.*)$").captures | map(.string))
            as $captures |
          ($captures[0] | strptime("%Y-%m-%d") | mktime) as $date |
          $captures[1] as $text |

          select(now >= $date) |

          ($text | test("\\[URGENT]"; "i")) as $urgent |
          (if $urgent then "38;5;196" else "38;5;208" end) as $sgr |
          if $urgent then sub("\\s*\\[URGENT]\\s*"; " "; "i") else . end |

          "\u001b[\($sgr)m\(.)\u001b[m"
        ) |
        if length == 0 then "nothing to remind" else .[] end
      ''}
    else
      echo "$TODO_file: no such file or directory"
    fi
  '';

in
# bash needed for <(...)
pkgs.writeBashBin "q" ''
  set -eu
  export PATH=/var/empty
  ${q-cal}
  ${q-utcdate}
  ${q-isodate}
  ${q-sgtdate}
  (${q-gitdir}) &
  (${q-intel_backlight}) &
  (${q-power_supply}) &
  (${q-virtualization}) &
  (${q-wireless}) &
  (${q-online}) &
  (${q-thermal_zone}) &
  wait
  if test "$PWD" != "$HOME" && test -e "$HOME/TODO"; then
    TODO_home_entries=$(cd; (${q-todo}) | ${pkgs.coreutils}/bin/wc -l)
    if test "$TODO_home_entries" = 1; then
      TODO_format='There is %d entry in ~/TODO'
    else
      TODO_format='There are %d entries in ~/TODO'
    fi
    printf "\x1b[38;5;238m$TODO_format\x1b[m\n" "$TODO_home_entries"
  fi
  (${q-todo}) || :
''